##--##--##--##--##borrowed from EFL autoconf (LGPL)##--thanks rasties!##
m4_define([v_maj], [1])
m4_define([v_min], [0])
m4_define([v_mic], [0])
m4_define([v_rev], m4_esyscmd([(svnversion -n "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git svn log --limit 1 --oneline 2>| /dev/null | sed -e 's/r\([0-9]\+\).*/\1/' | tr -d '\n' || echo 0000]))])
m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
##--##--##--##--##

AC_PREREQ([2.57])
AC_INIT([zpoll],[v_ver],[dev@zentific.com])
AC_CONFIG_SRCDIR([Makefile.am])
AM_CONFIG_HEADER(config.h)

AC_CANONICAL_BUILD
AC_CANONICAL_HOST
AC_GNU_SOURCE
AC_ISC_POSIX

AM_INIT_AUTOMAKE([foreign 1.7])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])

AC_DEFINE_UNQUOTED(ZENTIFIC_REVISION, [v_rev], [Revison])

AC_PROG_MAKE_SET
# Checks for programs.
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S

PKG_CHECK_MODULES([OPENSSL], [libssl >= 0.9.8])
PKG_CHECK_MODULES([ZSHARE], [libzshare])

#AC_CHECK_LIB([xenctrl], [lock_pages],[], AC_MSG_ERROR(Unable to find xenctrl),[-lpthread])
AC_CHECK_LIB([xenctrl], [xc_interface_open],[], AC_MSG_ERROR(Unable to find xenctrl),[-lpthread])
#this is the most hackish hack that was ever hacked
#but now it is slightly less hackish
AC_CHECKING([for legacy xen])
AC_CHECK_MEMBER(
       [xc_physinfo_t.nr_cpus],
       [AC_MSG_RESULT([nooooooooooooooope])],
       [
               AC_DEFINE([LEGACY_XEN],[1],[This Xen is ooooooooooooooold])
               AC_MSG_RESULT([this Xen is ooooooooooooooooold])
       ],
       [#include <xenctrl.h>]
)
AC_CHECK_LIB([xenstore], [xs_read],[], AC_MSG_ERROR(Unable to find xenstore),[-lpthread])


AC_ARG_ENABLE([debug], AS_HELP_STRING([--enable-debug],[enable debug mode @<:@default=yes@:>@]))
if test "x$enable_debug" != "xno";then
		CFLAGS+=" -ggdb -Wall "
		LDFLAGS+=" -rdynamic "
fi

ZPOLL_CHECK_DISTRO

AC_CONFIG_FILES([
Makefile
src/Makefile
src/defines.h
init/Makefile
init/debian/Makefile
init/ubuntu/Makefile
init/centos/Makefile
init/suse/Makefile
init/gentoo/Makefile
])
AC_OUTPUT