##--##--##--##--##borrowed from EFL autoconf (LGPL)##--thanks rasties!##
m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
##--##--##--##--##
AC_PREREQ([2.57])
AC_INIT([zensched],[0.6.0],[dev@zentific.com])
AC_CONFIG_SRCDIR([Makefile.am])
AC_CONFIG_MACRO_DIR([m4])
AM_CONFIG_HEADER(config.h)

AC_LIBTOOL_DLOPEN
AC_LIBLTDL_CONVENIENCE
AC_CANONICAL_BUILD
AC_CANONICAL_HOST
AC_GNU_SOURCE
AC_ISC_POSIX
AC_PROG_LIBTOOL
AC_SUBST(INCLTDL)
AC_SUBST(LIBLTDL)

AC_DEFINE_UNQUOTED(ZENTIFIC_REVISION, [v_rev], [Revison])

ZENSCHED_VERSION=1:0:0
AC_SUBST(ZENSCHED_VERSION)
AM_INIT_AUTOMAKE([foreign 1.7])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])

# Checks for programs.
AC_PROG_CC
AC_PROG_MAKE_SET
AM_PROG_CC_C_O

# Checks for library functions.
AC_FUNC_ALLOCA
AC_CHECK_FUNCS([getcwd])
libdir="${prefix}/zensched"

AC_CHECK_LIB([pthread], [pthread_create], [],AC_ERROR([Usable libpthread not found! check your libc installation!]))

# Checks for libraries.
AC_CHECK_LIB([dl], [dlopen], [],AC_ERROR([Usable libdl not found! check your libc installation!]))

PKG_CHECK_MODULES([ZSHARE], [libzshare])
PKG_CHECK_MODULES([ZXR], [libzxr])
PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.12.0 gobject-2.0])
PKG_CHECK_MODULES([OPENSSL], [libssl >= 0.9.8])
AC_SUBST(GLIB_CFLAGS)
AC_SUBST(GLIB_LIBS)
AC_SUBST(OPENSSL_CFLAGS)
AC_SUBST(OPENSSL_LIBS)

l="$LDFLAGS"
c="$CFLAGS"
CFLAGS="$GLIB_CFLAGS $ZXR_CFLAGS $ZSHARE_CFLAGS -I${prefix}/include"
LDFLAGS="$GLIB_LIBS $ZXR_LIBS $ZSHARE_LIBS -L${prefix}/zrpc"
b="$LIBS"
AC_CHECK_LIB([ztype], [VM_new], [], AC_ERROR([libztype not found! check your zrpc installation]))
AC_LINK_IFELSE(
	[AC_LANG_PROGRAM([
void *db;
void *config;],
[])],[], [AC_ERROR([libzcore not found! check your zrpc installation])])
CFLAGS="$c"
LDFLAGS="$l"
LIBS="$b"
ZTYPE_CFLAGS="-I${prefix}/include"
ZTYPE_LDFLAGS="-L${prefix}/zrpc"
ZCORE_CFLAGS="$ZTYPE_CFLAGS"
ZCORE_LDFLAGS="$ZTYPE_LDFLAGS"
AC_SUBST(ZTYPE_CFLAGS)
AC_SUBST(ZTYPE_LDFLAGS)
AC_SUBST(ZCORE_CFLAGS)
AC_SUBST(ZCORE_LDFLAGS)

AC_PATH_PROG([mysql_config], [mysql_config])
if test "x$mysql_config" != "x";then
      AC_CHECK_HEADERS([mysql/mysql.h])
      MYSQL_CFLAGS="$($mysql_config --cflags)"
      MYSQL_LIBS="$($mysql_config --libs_r)"
else
      AC_ERROR([could not find mysql_config, please make sure that you have a working mysql installation.])
fi
AC_SUBST(MYSQL_CFLAGS)
AC_SUBST(MYSQL_LIBS)

AC_ARG_ENABLE([python],
  AC_HELP_STRING([--enable-python], [Build python module support @<:@default=detect@:>@]),[],[want_python=$enableval])

if test "x$enable_shared:$want_python" = "xno:yes"; then
  AC_MSG_ERROR([Disabling shared libraries is incompatible with building Python extensions.])
fi

if test "x$want_python" != "xno" ; then
  AM_PATH_PYTHON(2.4)
  AM_CHECK_PYTHON_HEADERS(,[AC_MSG_ERROR(could not find Python headers)])
  if test "x$PYTHON" != ':';then
    PYTHON_LIBS="$($PYTHON-config --libs)"
    (test -n "$PYTHON_LIBS") && have_python=yes
  fi
fi
AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
AC_SUBST([PYTHON_LIBS])
AC_SUBST([PYTHON_VERSION])
AC_SUBST([PYTHON_INCLUDES])

AC_C___ATTRIBUTE__
AC_ARG_ENABLE([debug], AS_HELP_STRING([--enable-debug],[enable debug mode @<:@default=yes@:>@]))
if test "x$enable_debug" != "xno";then
		CFLAGS+=" -ggdb -Wall "
		LDFLAGS+=" -rdynamic "
fi

ZENSCHED_CHECK_DISTRO

AC_CONFIG_FILES([
Makefile
modules/Makefile
modules/python/Makefile
modules/python/zmail/Makefile
modules/python/update-checker/Makefile
modules/shell/Makefile
modules/shell/xen-legacy/Makefile
modules/shell/lvm/Makefile
modules/shell/libvirt/Makefile
modules/shell/gluster/Makefile
modules/shell/gluster-legacy/Makefile
src/Makefile
utils/Makefile
init/Makefile
init/debian/Makefile
init/ubuntu/Makefile
init/centos/Makefile
init/suse/Makefile
init/gentoo/Makefile
])
AC_OUTPUT