AC_PREREQ(2.57)
AC_INIT([libzxr],[0.6],[dev@zentific.com],[libzxr])
AC_CONFIG_SRCDIR([Makefile.am])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_HEADER([config.h])

AC_LIBTOOL_DLOPEN
AC_LIBLTDL_CONVENIENCE
AC_GNU_SOURCE
AC_PROG_LIBTOOL
AC_CANONICAL_BUILD
AC_CANONICAL_HOST
AC_ISC_POSIX
AC_SUBST(INCLTDL)
AC_SUBST(LIBLTDL)

AM_INIT_AUTOMAKE([foreign])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
LIB_ZXR_VERSION=1:0
AC_SUBST(LIB_ZXR_VERSION)

AC_PROG_INSTALL
AC_PROG_CC
AM_PROG_CC_C_O
AC_PROG_MAKE_SET

# check for dependencies
AC_PATH_PROG(RE2C, [re2c])
if test -z "$RE2C" ; then
	AC_MSG_ERROR([could not find re2c!])
fi

GLIB_REQUIRES="glib-2.0 >= 2.12.0 gthread-2.0 >= 2.12.0"
XML_REQUIRES="libxml-2.0 >= 2.6.20"
SSL_REQUIRES="libssl libcrypto"
JSON_REQUIRES="json-glib-1.0 >= 0.3"

if test "$libdir" = '${exec_prefix}/lib';then
	(pkg-config --cflags glib-2.0 | grep -q lib64) && libdir='${exec_prefix}/lib64'
fi

PKG_CHECK_MODULES(GLIB, [$GLIB_REQUIRES])
PKG_CHECK_MODULES(XML, [$XML_REQUIRES])
PKG_CHECK_MODULES(SSL, [$SSL_REQUIRES])
AC_ARG_ENABLE([json], AS_HELP_STRING([--enable-json],[enable jsonrpc @<:@default=detect@:>@]))
if test "x$enable_json" != "xno";then
	PKG_CHECK_MODULES(JSON, [$JSON_REQUIRES], [have_json=yes], [have_json=no], [build JSON transport], [yes])
	if test "x$have_json" = "xyes";then
		AC_DEFINE([ZXR_JSON_ENABLED],[1],[enable json support])
	else
		JSON_REQUIRES=""
		JSON_CFLAGS=""
		JSON_LIBS=""
	fi
else
	have_json=no
	JSON_REQUIRES=""
	JSON_CFLAGS=""
	JSON_LIBS=""
fi

AC_SUBST(GLIB_REQUIRES)
AC_SUBST(XML_REQUIRES)
AC_SUBST(SSL_REQUIRES)
AC_SUBST(JSON_REQUIRES)

# use g_regexp_*() on modern glib
if pkg-config 'glib-2.0 >= 2.14.0';then
  AC_DEFINE(HAVE_GLIB_REGEXP, 1, [whether glib supports regexps])
fi

AC_ARG_ENABLE([debug], AS_HELP_STRING([--enable-debug],[enable debug mode @<:@default=yes@:>@]))
if test "x$enable_debug" != "xno";then
		CFLAGS+=" -ggdb -rdynamic -Wall "
fi

# enable compiler warnings
if $CC --version | head -n1 | grep '(GCC) 4\.' &>/dev/null;then
  CFLAGS+=" -Wno-pointer-sign"
fi

# write output
AC_CONFIG_FILES([
  Makefile
  lib/Makefile
  zxdl-compiler/Makefile
  docs/Makefile
  libzxr.pc
])
AC_OUTPUT

echo 
echo "libzxr is now configured"
echo
echo "  xml-rpc transport: yes"
echo "  json transport:    $have_json"
echo